Mac Magazin/MacEasy 19/Mac Magazin and MacEasy Magazine CD - Issue 19.iso/Grafik & Text & Film/Quark XTensions/Freeware Xtensions/XPress Scripts 1.0/Linotronic 330 Setup/Linotronic 330 Setup

Text File | 1994-08-10 | 7KB | 164 lines

tell application "QuarkXPress 3.3"
    activate
    if document 1 exists then

        set maxFilmWidth to 305.481
        set paperWidth to 305
        set printerType to "Linotronic"

        copy page height of document 1 as integer to pageHeight
        copy page width of document 1 as integer to pageWidth
        copy registration marks offset to singleDocOffset
        copy (singleDocOffset / 2.83) * 4 to docOffsets
        copy pageHeight + docOffsets to pageAndOffsetHeight
        copy pageWidth + docOffsets to pageAndOffsetWidth

        tell document 1
            copy number of pages of current spread to PagesPerSpread
            set docName to name

            copy (display dialog "Linotronic 330 Print Setup for:" & return & "'" & docName & "'" buttons {"Cancel", "Setup..."} default button 2 with icon 2000) to x
            do updates
            if button returned of x is "Setup..." then
                if pageAndOffsetHeight > maxFilmWidth and pageAndOffsetWidth > maxFilmWidth then
                    beep
                    display dialog "Page size of this document is too" & return & ¬
                        "large for Linotronic 330. Check page" & return & "size and/or registration mark offsets." buttons "OK" default button 1 with icon 0
                    do updates
                else
                    tell print setup

                        set adjust horizontal tile to false
                        set auto tile overlap to 0
                        set back to front to false
                        set calibrated output to false
                        set collate to false
                        set data format to binary data
                        set flip vertical to false
                        set font substitution to false
                        set graphics smoothing to false
                        set include blank pages to false
                        set larger print area to false
                        set page gap to 0
                        set page sequence to all pages
                        set paper offset to 0
                        set print colors as grays to false
                        set print quality to normal
                        set print thumbnails to false
                        set reduce or enlarge to 100
                        set registration marks to centered
                        set separation to true
                        set text smoothing to false
                        set tiling to off
                        set unlimited downloadable fonts to false
                        set use PDF screen values to false
                    end tell

                    copy text returned of (display dialog "Halftone screen:" default answer ¬
                        "150" buttons {"  Okay  "} default button 1 with icon 2001) to halftoneScreen
                    do updates
                    copy halftoneScreen as real to halftoneScreen
                    try
                        if halftoneScreen ≥ 65 and halftoneScreen < 75 then
                            copy "1270" to printRes
                        else if halftoneScreen ≥ 75 and halftoneScreen < 85 then
                            copy "1693" to printRes
                        else if halftoneScreen ≥ 85 and halftoneScreen < 133 then
                            copy "2032" to printRes
                        else if halftoneScreen ≥ 133 and halftoneScreen ≤ 175 then
                            copy "2540" to printRes
                        else if halftoneScreen > 175 and halftoneScreen ≤ 200 then
                            copy "3386" to printRes
                        else
                            error number -130
                        end if

                        copy (display dialog "Film output:" & return & " " buttons {"Negative", "Positive"} default button 2 with icon 2001) to filmOutput
                        do updates
                        if button returned of filmOutput is "Negative" then
                            copy true to filmState
                        else if button returned of filmOutput is "Positive" then
                            copy false to filmState
                        end if

                        copy (display dialog "Film emulsion:" & return & " " buttons {"Up", " Down "} default button 2 with icon 2001) to filmEmulsion
                        do updates
                        if button returned of filmEmulsion is "Up" then
                            copy false to filmEmuls
                        else if button returned of filmEmulsion is " Down " then
                            copy true to filmEmuls
                        end if

                        if pageAndOffsetHeight < maxFilmWidth and pageAndOffsetWidth < maxFilmWidth and pageAndOffsetHeight < pageAndOffsetWidth then
                            copy portrait to filmOrientation
                        else if pageAndOffsetHeight < maxFilmWidth and pageAndOffsetWidth < maxFilmWidth and pageAndOffsetHeight > pageAndOffsetWidth then
                            copy landscape to filmOrientation
                        else if pageAndOffsetHeight < maxFilmWidth and pageAndOffsetWidth > maxFilmWidth then
                            copy landscape to filmOrientation
                        else if pageAndOffsetHeight < pageAndOffsetWidth then
                            copy portrait to filmOrientation
                        else if pageAndOffsetHeight > maxFilmWidth and pageAndOffsetWidth < maxFilmWidth then
                            copy portrait to filmOrientation
                        end if

                        copy (display dialog "Spreads:" & return & " " buttons {"On", "   Off   "} default button 2 with icon 2001) to docSpreadsDLOG
                        do updates
                        if button returned of docSpreadsDLOG is "On" then
                            copy true to docSpreads
                            copy (pageAndOffsetWidth * 2) - (singleDocOffset * 2) to doublePageAndOffsetWidth

                            if doublePageAndOffsetWidth > maxFilmWidth and pageAndOffsetHeight < maxFilmWidth and filmOrientation = portrait then
                                copy landscape to filmOrientation
                            else if doublePageAndOffsetWidth > 305.481 and filmOrientation = portrait then
                                beep
                                display dialog "Page size of this document is too" & return & ¬
                                    "large for Linotronic 330. Check page" & return & "size and/or registration mark offsets." buttons "OK" default button 1 with icon 0
                                do updates
                                error number -128
                            else if pageAndOffsetHeight < maxFilmWidth and doublePageAndOffsetWidth < maxFilmWidth and pageAndOffsetHeight < doublePageAndOffsetWidth then
                                copy portrait to filmOrientation
                            else if pageAndOffsetHeight < maxFilmWidth and doublePageAndOffsetWidth < maxFilmWidth and pageAndOffsetHeight > doublePageAndOffsetWidth then
                                copy landscape to filmOrientation
                            else if pageAndOffsetHeight < maxFilmWidth and doublePageAndOffsetWidth > maxFilmWidth then
                                copy landscape to filmOrientation
                            else if pageAndOffsetHeight < doublePageAndOffsetWidth then
                                copy portrait to filmOrientation
                            else if pageAndOffsetHeight > maxFilmWidth and doublePageAndOffsetWidth < maxFilmWidth then
                                copy portrait to filmOrientation
                            end if

                        else if button returned of docSpreadsDLOG is "   Off   " then
                            copy false to docSpreads
                        end if

                        tell print setup

                            set printer type to printerType --**
                            set paper width to paperWidth --**
                            set flip horizontal to filmEmuls --**
                            set orientation to filmOrientation --**
                            set halftone screen to halftoneScreen --**
                            set invert image to filmState --**
                            set print spreads to docSpreads --**
                            set resolution to printRes --**

                            set font substitution to false --these 3 repeated to be sure that they will be off
                            set graphics smoothing to false --(they occasionally do not turn off)
                            set text smoothing to false

                        end tell
                    on error number -130
                        beep
                        display dialog "Invalid entry for halftone screen." & return & "‘" & halftoneScreen & "’ cannot be used." buttons "Cancel" default button 1 with icon 1
                        do updates
                    end try
                end if
            end if
        end tell
    else
        beep
        display dialog "This script requires an" & return & "open QuarkXPress document." buttons "  Okay  " default button 1 with icon 1
        do updates
    end if
end tell